Add php7 return type hint support

Fixes: #101

Author: dudu

autoload/phpcomplete.vim

@@ -1680,23 +1680,28 @@ function! phpcomplete#GetCallChainReturnType(classname_candidate, class_candidat
 			for classstructure in classcontents
 				let docblock_target_pattern = 'function\s\+&\?'.method.'\>\|\(public\|private\|protected\|var\).\+\$'.method.'\>\|@property.\+\$'.method.'\>'
 				let doc_str = phpcomplete#GetDocBlock(split(classstructure.content, '\n'), docblock_target_pattern)
-				if doc_str != ''
+				let return_type_hint = phpcomplete#GetFunctionReturnTypeHint(split(classstructure.content, '\n'), 'function\s\+&\?'.method.'\>')
+				if doc_str != '' || return_type_hint != ''
 					break
 				endif
 			endfor
-			if doc_str != ''
+			if doc_str != '' || return_type_hint != ''
 				let docblock = phpcomplete#ParseDocBlock(doc_str)
-				if has_key(docblock.return, 'type') || has_key(docblock.var, 'type') || len(docblock.properties) > 0
-					let type = has_key(docblock.return, 'type') ? docblock.return.type : has_key(docblock.var, 'type') ? docblock.var.type : ''
-
-					if type == ''
-						for property in docblock.properties
-							if property.description =~? method
-								let type = property.type
-								break
-							endif
-						endfor
-					endif
+				if has_key(docblock.return, 'type') || has_key(docblock.var, 'type') || len(docblock.properties) > 0 || return_type_hint != ''
+					if return_type_hint == ''
+						let type = has_key(docblock.return, 'type') ? docblock.return.type : has_key(docblock.var, 'type') ? docblock.var.type : ''
+
+						if type == ''
+							for property in docblock.properties
+								if property.description =~? method
+									let type = property.type
+									break
+								endif
+							endfor
+						endif
+					else
+						let type = return_type_hint
+					end
 
 					" there's a namespace in the type, threat the type as FQCN
 					if type =~ '\\'
@@ -1874,9 +1879,11 @@ function! phpcomplete#GetClassName(start_line, context, current_namespace, impor
 		elseif function_file != '' && filereadable(function_file)
 			let file_lines = readfile(function_file)
 			let docblock_str = phpcomplete#GetDocBlock(file_lines, 'function\s*&\?\<'.function_name.'\>')
+			let return_type_hint = phpcomplete#GetFunctionReturnTypeHint(file_lines, 'function\s*&\?'.function_name.'\>')
 			let docblock = phpcomplete#ParseDocBlock(docblock_str)
-			if has_key(docblock.return, 'type')
-				let classname_candidate = docblock.return.type
+			let type = has_key(docblock.return, 'type') ? docblock.return.type : return_type_hint
+			if type != ''
+				let classname_candidate = type
 				let [class_candidate_namespace, function_imports] = phpcomplete#GetCurrentNameSpace(file_lines)
 				" try to expand the classname of the returned type with the context got from the function's source file
 
@@ -2108,9 +2115,11 @@ function! phpcomplete#GetClassName(start_line, context, current_namespace, impor
 				elseif function_file != '' && filereadable(function_file)
 					let file_lines = readfile(function_file)
 					let docblock_str = phpcomplete#GetDocBlock(file_lines, 'function\s*&\?\<'.function_name.'\>')
+					let return_type_hint = phpcomplete#GetFunctionReturnTypeHint(file_lines, 'function\s*&\?'.function_name.'\>')
 					let docblock = phpcomplete#ParseDocBlock(docblock_str)
-					if has_key(docblock.return, 'type')
-						let classname_candidate = docblock.return.type
+					let type = has_key(docblock.return, 'type') ? docblock.return.type : return_type_hint
+					if type != ''
+						let classname_candidate = type
 						let [class_candidate_namespace, function_imports] = phpcomplete#GetCurrentNameSpace(file_lines)
 						" try to expand the classname of the returned type with the context got from the function's source file
 						let [classname_candidate, class_candidate_namespace] = phpcomplete#ExpandClassName(classname_candidate, class_candidate_namespace, function_imports)
@@ -2703,6 +2712,44 @@ function! phpcomplete#ParseDocBlock(docblock) " {{{
 endfunction
 " }}}
 
+function! phpcomplete#GetFunctionReturnTypeHint(sccontent, search)
+	let i = 0
+	let l = 0
+	let function_line_start = -1
+	let function_line_end = -1
+	let sccontent_len = len(a:sccontent)
+	let return_type = ''
+
+	while (i < sccontent_len)
+		let line = a:sccontent[i]
+		" search for a function declaration
+		if line =~? a:search
+			let l = i
+			let function_line_start = i
+			" now search for the first { where the function body starts
+			while l < sccontent_len
+				let line = a:sccontent[l]
+				if line =~? '\V{'
+					let function_line_end = l
+					break
+				endif
+				let l += 1
+			endwhile
+			break
+		endif
+		let i += 1
+	endwhile
+
+	" now grab the lines that holds the function declaration line
+	if function_line_start != -1 && function_line_end != -1
+		let function_line = join(a:sccontent[function_line_start :function_line_end], " ")
+		let class_name_pattern = '[a-zA-Z_\x7f-\xff\\][a-zA-Z_0-9\x7f-\xff\\]*'
+		let return_type = matchstr(function_line, '\c\s*:\s*\zs'.class_name_pattern.'\ze\s*{')
+	endif
+	return return_type
+
+endfunction
+
 function! phpcomplete#GetTypeFromDocBlockParam(docblock_type) " {{{
 	if a:docblock_type !~ '|'
 		return a:docblock_type

tests/GetClassName_test.vim

@@ -897,4 +897,27 @@ fun! TestCase_resolves_inside_a_function_body()
     silent! bw! %
 endf
 
+fun! TestCase_resolves_return_type_hints()
+    call SetUp()
+
+    let path = expand('%:p:h')."/"."fixtures/GetClassName/return_typehinted_functions.php"
+    below 1new
+    exe ":silent! edit ".path
+    exe 'let b:phpbegin = [0, 0]'
+
+    exe ':24'
+    let classname = phpcomplete#GetClassName(24, '$f->', '', {})
+    call VUAssertEquals('FooReturnBars', classname)
+
+    exe ':26'
+    let classname = phpcomplete#GetClassName(26, '$f->returnBar()->', '', {})
+    call VUAssertEquals('Bar', classname)
+
+    exe ':28'
+    let classname = phpcomplete#GetClassName(28, '$f->returnBar2()->', '', {})
+    call VUAssertEquals('Bar2', classname)
+
+    silent! bw! %
+endf
+
 " vim: foldmethod=marker:expandtab:ts=4:sts=4

tests/GetFunctionReturnTypeHint_test.vim

@@ -0,0 +1,20 @@
+fun! SetUp()
+    " disable builtin information
+    let g:php_builtin_functions = {}
+    " disable tag files
+    exe ':set tags='
+    let g:fixture_file_content = readfile(expand('%:p:h').'/'.'fixtures/GetFunctionReturnTypeHint/functions.php')[2:]
+endf
+
+fun! TestCase_return_current_file_path_when_function_declaration_is_found_in_the_file()
+    call SetUp()
+
+    let ret = phpcomplete#GetFunctionReturnTypeHint(g:fixture_file_content, 'function\s*\<returnFoo\>')
+    call VUAssertEquals('Foo', ret)
+
+    let ret = phpcomplete#GetFunctionReturnTypeHint(g:fixture_file_content, 'function\s*\<returnBar\>')
+    call VUAssertEquals('Bar', ret)
+
+    let ret = phpcomplete#GetFunctionReturnTypeHint(g:fixture_file_content, 'function\s*\<returnBar2\>')
+    call VUAssertEquals('Bar2', ret)
+endf

tests/fixtures/GetClassName/return_typehinted_functions.php

@@ -0,0 +1,29 @@
+<?php
+
+class Bar {
+	public function findMe() { }
+}
+
+class Bar2 {
+	public function findMe() { }
+}
+
+class FooReturnBars {
+	public function returnBar($a, $b = 'foo') : Bar {
+	}
+
+	public function returnBar2($a, $b = 'foo') : Bar2
+	{
+	}
+}
+
+function returnFoo() : FooReturnBars {
+}
+
+$f = returnFoo();
+$f->
+;
+$f->returnBar()->
+;
+$f->returnBar2()->
+;

tests/fixtures/GetFunctionReturnTypeHint/functions.php

@@ -0,0 +1,14 @@
+<?php
+
+class Foo
+	public function returnBar($a, $b = 'foo') : Bar {
+	}
+
+	public function returnBar2($a, $b = 'foo') : Bar2
+	{
+	}
+}
+
+function returnFoo() : Foo {
+
+}