add freelook camera

Author: NathanLovato

addons/free_camera.gd

@@ -0,0 +1,63 @@
+class_name FreelookCamera3D extends Camera3D
+
+@export var movement_speed := 10
+@export var mouse_sensitivity := 0.006
+
+var _previous_camera: Camera3D
+var _camera_input_direction := Vector2.ZERO
+
+
+func _ready() -> void:
+	current = false
+	process_mode = PROCESS_MODE_ALWAYS
+	set_process(current)
+
+
+func _input(event: InputEvent) -> void:
+	if event.is_action_pressed("toggle_freelook_camera"):
+		_toggle_camera_mode()
+
+	if current:
+		var is_camera_motion := (
+			event is InputEventMouseMotion and
+			Input.get_mouse_mode() == Input.MOUSE_MODE_CAPTURED
+		)
+		if is_camera_motion:
+			_camera_input_direction = event.relative * mouse_sensitivity
+
+
+func _process(delta: float) -> void:
+	var movement := Vector3.ZERO
+	if Input.is_key_pressed(KEY_W):
+		movement += Vector3.FORWARD
+	if Input.is_key_pressed(KEY_A):
+		movement += Vector3.LEFT
+	if Input.is_key_pressed(KEY_S):
+		movement += Vector3.BACK
+	if Input.is_key_pressed(KEY_D):
+		movement += Vector3.RIGHT
+	if Input.is_key_pressed(KEY_Q):
+		movement += Vector3.DOWN
+	if Input.is_key_pressed(KEY_E):
+		movement += Vector3.UP
+
+	rotation.x -= _camera_input_direction.y
+	rotation.x = clampf(rotation.x, -PI / 2.0, PI / 2.0)
+	rotation.y -= _camera_input_direction.x
+
+	global_position += global_transform.basis * movement * delta * movement_speed
+
+	_camera_input_direction = Vector2.ZERO
+
+
+func _toggle_camera_mode() -> void:
+	if not current:
+		_previous_camera = get_viewport().get_camera_3d()
+		fov = _previous_camera.fov
+		global_transform = _previous_camera.global_transform
+		make_current()
+	else:
+		_previous_camera.make_current()
+
+	get_tree().paused = current
+	set_process(current)

game.tscn

@@ -1,7 +1,8 @@
-[gd_scene load_steps=5 format=3 uid="uid://bvt4747kc5u2t"]
+[gd_scene load_steps=6 format=3 uid="uid://bvt4747kc5u2t"]
 
 [ext_resource type="Script" path="res://game.gd" id="1_1il7v"]
 [ext_resource type="PackedScene" uid="uid://b1ot6gn6tms6h" path="res://lesson_reference/player_3d_template.tscn" id="1_w0p8v"]
+[ext_resource type="Script" path="res://addons/free_camera.gd" id="5_5y4mc"]
 [ext_resource type="PackedScene" uid="uid://cnedxfn2pxh2t" path="res://level/level.tscn" id="7_2frud"]
 [ext_resource type="PackedScene" uid="uid://bxg6oejpaitdt" path="res://level/interactable/flag/flag_reached_screen.tscn" id="19_cpgj4"]
 
@@ -15,3 +16,6 @@ transform = Transform3D(1, 0, 0, 0, 1, 0, 0, 0, 1, 2.43638, 0, -7.8513)
 
 [node name="Level" parent="." instance=ExtResource("7_2frud")]
 transform = Transform3D(1, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 31.4)
+
+[node name="FreelookCamera3D" type="Camera3D" parent="."]
+script = ExtResource("5_5y4mc")

project.godot

@@ -74,6 +74,11 @@ left_click={
 "events": [Object(InputEventMouseButton,"resource_local_to_scene":false,"resource_name":"","device":-1,"window_id":0,"alt_pressed":false,"shift_pressed":false,"ctrl_pressed":false,"meta_pressed":false,"button_mask":0,"position":Vector2(0, 0),"global_position":Vector2(0, 0),"factor":1.0,"button_index":1,"canceled":false,"pressed":false,"double_click":false,"script":null)
 ]
 }
+toggle_freelook_camera={
+"deadzone": 0.5,
+"events": [Object(InputEventKey,"resource_local_to_scene":false,"resource_name":"","device":-1,"window_id":0,"alt_pressed":false,"shift_pressed":false,"ctrl_pressed":false,"meta_pressed":false,"pressed":false,"keycode":0,"physical_keycode":4194341,"key_label":0,"unicode":0,"location":0,"echo":false,"script":null)
+]
+}
 
 [rendering]