support find_package()

Author: baldwin-law

CMakeLists.txt

@@ -1,7 +1,7 @@
 #
 # cpp-tbox
 #
-cmake_minimum_required(VERSION 3.10)
+cmake_minimum_required(VERSION 3.15)
 
 #
 # Building in-tree is not allowed (we take care of your craziness).
@@ -27,14 +27,14 @@ set(TBOX_VERSION_REVISION ${CMAKE_MATCH_1})
 set(TBOX_VERSION ${TBOX_VERSION_MAJOR}.${TBOX_VERSION_MINOR}.${TBOX_VERSION_REVISION})
 
 
+
 #
 # Set install prefix
 #
 #set(CMAKE_INSTALL_PREFIX "${CMAKE_CURRENT_SOURCE_DIR}/install" CACHE PATH "")
 
-
 project(
-    tbox
+    cpp-tbox
     VERSION ${TBOX_VERSION}
     DESCRIPTION "Easy to use, convenient and modern C++ treasure box!"
     HOMEPAGE_URL "https://gitee.com/cpp-master/cpp-tbox"
@@ -76,7 +76,7 @@ option(TBOX_ENABLE_NLOHMANN_JSON "install nlohmann/json" ON)
 #
 # TESTS
 #
-option(CMAKE_ENABLE_TEST "Whether to enable unit tests" OFF)
+option(CMAKE_ENABLE_TEST "Whether to enable unit tests" ON)
 
 if(CMAKE_ENABLE_TEST)
     message(STATUS "Unit tests enabled")
@@ -85,92 +85,128 @@ if(CMAKE_ENABLE_TEST)
     enable_testing()
 endif()
 
+include(GNUInstallDirs)
 
 #
 # Compiler args
 #
 set(CMAKE_C_STANDARD 99)
 set(CMAKE_CXX_STANDARD 11)
 add_compile_options(-Wall -Wextra -Werror -Wno-missing-field-initializers)
+
 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/3rd-party)
 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/modules)
 
 add_definitions(-DTBOX_VERSION_MAJOR=${TBOX_VERSION_MAJOR}
                 -DTBOX_VERSION_MINOR=${TBOX_VERSION_MINOR}
                 -DTBOX_VERSION_REVISION=${TBOX_VERSION_REVISION})
 
+set(TBOX_COMPONENTS)
+
 if(TBOX_ENABLE_BASE)
     message(STATUS "base module enabled")
-    add_subdirectory(modules/base)
+    list(APPEND TBOX_COMPONENTS base)
 endif()
 
 if(TBOX_ENABLE_UTIL)
     message(STATUS "util module enabled")
-    add_subdirectory(modules/util)
+    list(APPEND TBOX_COMPONENTS util)
 endif()
 
 if(TBOX_ENABLE_EVENT)
     message(STATUS "event module enabled")
-    add_subdirectory(modules/event)
+    list(APPEND TBOX_COMPONENTS event)
 endif()
 
 if(TBOX_ENABLE_EVENTX)
     message(STATUS "eventx module enabled")
-    add_subdirectory(modules/eventx)
+    list(APPEND TBOX_COMPONENTS eventx)
 endif()
 
 if(TBOX_ENABLE_LOG)
     message(STATUS "log module enabled")
-    add_subdirectory(modules/log)
+    list(APPEND TBOX_COMPONENTS log)
 endif()
 
 if(TBOX_ENABLE_NETWORK)
     message(STATUS "network module enabled")
-    add_subdirectory(modules/network)
+    list(APPEND TBOX_COMPONENTS network)
 endif()
 
 if(TBOX_ENABLE_TERMINAL)
     message(STATUS "terminal module enabled")
-    add_subdirectory(modules/terminal)
+    list(APPEND TBOX_COMPONENTS terminal)
 endif()
 
 if(TBOX_ENABLE_MAIN)
     message(STATUS "main module enabled")
-    add_subdirectory(modules/main)
+    list(APPEND TBOX_COMPONENTS main)
 endif()
 
 if(TBOX_ENABLE_COROUTINE)
     message(STATUS "coroutine module enabled")
-    add_subdirectory(modules/coroutine)
+    list(APPEND TBOX_COMPONENTS coroutine)
 endif()
 
 if(TBOX_ENABLE_HTTP)
     message(STATUS "http module enabled")
-    add_subdirectory(modules/http)
+    list(APPEND TBOX_COMPONENTS http)
 endif()
 
 if(TBOX_ENABLE_MQTT)
     message(STATUS "mqtt module enabled")
-    add_subdirectory(modules/mqtt)
+    list(APPEND TBOX_COMPONENTS mqtt)
 endif()
 
 if(TBOX_ENABLE_FLOW)
     message(STATUS "flow module enabled")
-    add_subdirectory(modules/flow)
+    list(APPEND TBOX_COMPONENTS flow)
 endif()
 
 if(TBOX_ENABLE_ALARM)
     message(STATUS "alarm module enabled")
-    add_subdirectory(modules/alarm)
+    list(APPEND TBOX_COMPONENTS alarm)
 endif()
 
 if(TBOX_ENABLE_CRYPTO)
     message(STATUS "crypto module enabled")
-    add_subdirectory(modules/crypto)
+    list(APPEND TBOX_COMPONENTS crypto)
 endif()
 
+
+foreach(item IN LISTS TBOX_COMPONENTS)
+    add_subdirectory(modules/${item})
+endforeach()
+
 if(TBOX_ENABLE_NLOHMANN_JSON)
     message(STATUS "nlohmann/json installation enabled")
+    list(APPEND TBOX_COMPONENTS nlohmann)
     add_subdirectory(3rd-party/nlohmann)
 endif()
 
+#
+# installation
+#
+include(CMakePackageConfigHelpers)
+
+# generate the version file for the config file
+write_basic_package_version_file(
+  "${CMAKE_CURRENT_BINARY_DIR}/tboxConfigVersion.cmake"
+  VERSION "${TBOX_VERSION}"
+  COMPATIBILITY AnyNewerVersion
+)
+
+configure_package_config_file(
+    ${CMAKE_CURRENT_SOURCE_DIR}/Config.cmake.in
+    "${CMAKE_CURRENT_BINARY_DIR}/tboxConfig.cmake"
+    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/tbox
+    PATH_VARS TBOX_COMPONENTS
+)
+
+install(
+    FILES
+    "${CMAKE_CURRENT_BINARY_DIR}/tboxConfig.cmake"
+    "${CMAKE_CURRENT_BINARY_DIR}/tboxConfigVersion.cmake"
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/tbox
+)
+

Config.cmake.in

@@ -0,0 +1,11 @@
+@PACKAGE_INIT@
+
+set(_cpp_tbox_supported_components "@TBOX_COMPONENTS@")
+
+foreach(_comp ${tbox_FIND_COMPONENTS})
+  if (NOT _comp IN_LIST _cpp_tbox_supported_components)
+      set(tbox_FOUND False)
+      set(tbox_NOT_FOUND_MESSAGE "Unsupported component: ${_comp}, supported list: ${_cpp_tbox_supported_components}")
+  endif()
+  include("${CMAKE_CURRENT_LIST_DIR}/tbox_${_comp}_targets.cmake")
+endforeach()

README_CN.md

@@ -120,9 +120,17 @@ cmake -B build -DCMAKE_INSTALL_PREFIX=$HOME/.tbox
 ```
 
 # 使用教程
-关于如何使用 cpp-tbox 开发自己的程序，详见教程：
+1. 关于如何使用 cpp-tbox 开发自己的程序，详见教程：
 [cpp-tbox-tutorials](https://gitee.com/cpp-master/cpp-tbox-tutorials)  
 
+2. 使用CMake **find_package**:
+tbox 使用CMake的components构建, 使用库的方法如下(CMakeLists.txt):
+```
+find_package(tbox COMPONENTS base util alarm event eventx ... REQUIRED) or find_package(tbox COMPONENTS base REQUIRED PATHS /your/install/path)
+target_link_libraries(your_target PRIVATE tbox::tbox_base tbox::tbox_util tbox::tbox_alarm tbox::tbox_event tbox::tbox_eventx ...)
+```
+
+
 # 外部库依赖
 
 | 库名 | 依赖模块 | 说明 | 安装方法 |

modules/alarm/CMakeLists.txt

@@ -5,10 +5,10 @@ set(TBOX_ALARM_VERSION_MINOR 0)
 set(TBOX_ALARM_VERSION_PATCH 1)
 set(TBOX_ALARM_VERSION ${TBOX_ALARM_VERSION_MAJOR}.${TBOX_ALARM_VERSION_MINOR}.${TBOX_ALARM_VERSION_PATCH})
 
-project(tbox_alarm)
-
 add_definitions(-DLOG_MODULE_ID="tbox.alarm")
 
+set(TBOX_LIBRARY_NAME tbox_alarm)
+
 set(TBOX_ALARM_HEADERS
     alarm.h
     weekly_alarm.h
@@ -29,17 +29,43 @@ set(TBOX_ALARM_SOURCES
 set(TBOX_ALARM_TEST_SOURCES
     workday_calendar_test.cpp)
 
-add_library(${PROJECT_NAME} ${TBOX_BUILD_LIB_TYPE} ${TBOX_ALARM_SOURCES})
+add_library(${TBOX_LIBRARY_NAME} ${TBOX_BUILD_LIB_TYPE} ${TBOX_ALARM_SOURCES})
+add_library(tbox::${TBOX_LIBRARY_NAME} ALIAS ${TBOX_LIBRARY_NAME})
 
-set_target_properties(${PROJECT_NAME} PROPERTIES
-                        VERSION ${TBOX_ALARM_VERSION}
-                      SOVERSION ${TBOX_ALARM_VERSION_MAJOR})
+set_target_properties(
+    ${TBOX_LIBRARY_NAME} PROPERTIES
+    VERSION ${TBOX_ALARM_VERSION}
+    SOVERSION ${TBOX_ALARM_VERSION_MAJOR}
+)
 
 if(${TBOX_ENABLE_TEST})
-    add_executable(${PROJECT_NAME}_test ${TBOX_ALARM_TEST_SOURCES})
-    target_link_libraries(${PROJECT_NAME}_test gmock_main gmock gtest pthread ${PROJECT_NAME} tbox_base tbox_event rt dl)
-    add_test(NAME ${PROJECT_NAME}_test COMMAND ${PROJECT_NAME}_test)
+    add_executable(${TBOX_LIBRARY_NAME}_test ${TBOX_ALARM_TEST_SOURCES})
+
+    target_link_libraries(${TBOX_LIBRARY_NAME}_test gmock_main gmock gtest pthread ${TBOX_LIBRARY_NAME} tbox_base rt dl)
+    add_test(NAME ${TBOX_LIBRARY_NAME}_test COMMAND ${TBOX_LIBRARY_NAME}_test)
 endif()
 
-install(FILES ${TBOX_ALARM_HEADERS} DESTINATION include/tbox/alarm)
-install(TARGETS ${PROJECT_NAME} LIBRARY DESTINATION lib)
+# install the target and create export-set
+install(
+    TARGETS ${TBOX_LIBRARY_NAME}
+    EXPORT ${TBOX_LIBRARY_NAME}_targets
+    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+    INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+)
+
+# install header file
+install(
+    FILES ${TBOX_ALARM_HEADERS}
+    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/tbox/alarm
+)
+
+
+# generate and install export file
+install(
+    EXPORT ${TBOX_LIBRARY_NAME}_targets
+    FILE ${TBOX_LIBRARY_NAME}_targets.cmake
+    NAMESPACE tbox::
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/tbox
+)

modules/base/CMakeLists.txt

@@ -1,14 +1,12 @@
-cmake_minimum_required(VERSION 3.15)
-
 set(TBOX_BASE_VERSION_MAJOR 1)
 set(TBOX_BASE_VERSION_MINOR 0)
 set(TBOX_BASE_VERSION_PATCH 1)
 set(TBOX_BASE_VERSION ${TBOX_BASE_VERSION_MAJOR}.${TBOX_BASE_VERSION_MINOR}.${TBOX_BASE_VERSION_PATCH})
 
-project(tbox_base)
-
 add_definitions(-DLOG_MODULE_ID="tbox.base")
 
+set(TBOX_LIBRARY_NAME tbox_base)
+
 set(TBOX_BASE_HEADERS
     version.h
     log.h
@@ -45,18 +43,43 @@ set(TBOX_BASE_TEST_SOURCES
     catch_throw_test.cpp
     object_pool_test.cpp)
 
-add_library(${PROJECT_NAME} ${TBOX_BUILD_LIB_TYPE} ${TBOX_BASE_SOURCES})
+add_library(${TBOX_LIBRARY_NAME} ${TBOX_BUILD_LIB_TYPE} ${TBOX_BASE_SOURCES})
+add_library(tbox::${TBOX_LIBRARY_NAME} ALIAS ${TBOX_LIBRARY_NAME})
 
-set_target_properties(${PROJECT_NAME} PROPERTIES
-                        VERSION ${TBOX_BASE_VERSION}
-                      SOVERSION ${TBOX_BASE_VERSION_MAJOR})
+set_target_properties(
+    ${TBOX_LIBRARY_NAME} PROPERTIES
+    VERSION ${TBOX_BASE_VERSION}
+    SOVERSION ${TBOX_BASE_VERSION_MAJOR}
+)
 
 if(${TBOX_ENABLE_TEST})
-    add_executable(${PROJECT_NAME}_test ${TBOX_BASE_TEST_SOURCES})
+    add_executable(${TBOX_LIBRARY_NAME}_test ${TBOX_BASE_TEST_SOURCES})
 
-    target_link_libraries(${PROJECT_NAME}_test gmock_main gmock gtest pthread ${PROJECT_NAME} rt dl)
-    add_test(NAME ${PROJECT_NAME}_test COMMAND ${PROJECT_NAME}_test)
+    target_link_libraries(${TBOX_LIBRARY_NAME}_test gmock_main gmock gtest pthread ${TBOX_LIBRARY_NAME} rt dl)
+    add_test(NAME ${TBOX_LIBRARY_NAME}_test COMMAND ${TBOX_LIBRARY_NAME}_test)
 endif()
 
-install(FILES ${TBOX_BASE_HEADERS} DESTINATION include/tbox/base)
-install(TARGETS ${PROJECT_NAME} LIBRARY DESTINATION lib)
+# install the target and create export-set
+install(
+    TARGETS ${TBOX_LIBRARY_NAME}
+    EXPORT ${TBOX_LIBRARY_NAME}_targets
+    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+    INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+)
+
+# install header file
+install(
+    FILES ${TBOX_BASE_HEADERS}
+    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/tbox/base
+)
+
+
+# generate and install export file
+install(
+    EXPORT ${TBOX_LIBRARY_NAME}_targets
+    FILE ${TBOX_LIBRARY_NAME}_targets.cmake
+    NAMESPACE tbox::
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/tbox
+)