Supports requests using multipart/form-data

Author: fernand-o

src/RestClient.pas

@@ -230,6 +230,34 @@   TResource = class
     {$ENDIF}
   end;
 
+  {$IFDEF SUPPORTS_GENERICS}
+  TMultiPartFormAttachment = class
+  private
+    FFileName: string;
+    FMimeType: string;
+    FContent: TStringStream;
+  public
+    constructor Create(MimeType, FileName: string); overload;
+    constructor Create(Source: TStream; MimeType, FileName: string); overload;
+    constructor Create(FilePath, MimeType, FileName: string); overload;
+    destructor Destroy; override;
+    property Content: TStringStream read FContent write FContent;
+    property MimeType: string read FMimeType write FMimeType;
+    property FileName: string read FFileName write FFileName;
+  end;
+
+  TMultiPartFormData = class
+  private
+    FBoundary: string;
+    FContentType: string;
+    procedure AddFieldContent(Field: TRttiField; var Content: TStringList);
+  public
+    constructor Create;
+    function ContentAsString: string;
+    property ContentType: string read FContentType;
+  end;
+  {$ENDIF}
+
 implementation
 
 uses StrUtils, Math,
@@ -896,21 +924,29 @@ procedure TResource.GetAsDataSet(ADataSet: TDataSet);
 
 procedure TResource.SetContent(entity: TObject);
 var
-  vJson: string;
+  vRawContent: string;
   vStream: TStringStream;
+  vMultipartFormData: TMultipartFormData;
 begin
   FContent.Clear;
-  if Assigned(entity) then
+  if not Assigned(entity) then
+    Exit;
+
+  if entity is TMultipartFormData then
   begin
-     vJson := TJsonUtil.Marshal(Entity);
-
-    vStream := TStringStream.Create(vJson);
-    try
-      vStream.Position := 0;
-      FContent.CopyFrom(vStream, vStream.Size);
-    finally
-      vStream.Free;
-    end;
+    vMultipartFormData := TMultipartFormData(entity);
+    vRawContent := vMultipartFormData.ContentAsString;
+    ContentType(vMultipartFormData.ContentType);
+  end
+  else
+    vRawContent := TJsonUtil.Marshal(Entity);
+
+  vStream := TStringStream.Create(vRawContent);
+  try
+    vStream.Position := 0;
+    FContent.CopyFrom(vStream, vStream.Size);
+  finally
+    vStream.Free;
   end;
 end;
 
@@ -1016,4 +1052,94 @@ class function TJsonListAdapter.NewFrom(AList: TList; AItemClass: TClass): IJson
   Result := TJsonListAdapter.Create(AList, AItemClass);
 end;
 
+{ TMultiPartFormData }
+
+{$IFDEF SUPPORTS_GENERICS}
+procedure TMultiPartFormData.AddFieldContent(Field: TRttiField; var Content: TStringList);
+const
+  FmtTextContent = 'Content-Disposition: form-data; name="%s"'+ sLineBreak+sLineBreak +'%s';
+  FmtFileContent = 'Content-Disposition: form-data; name="%s"; filename="%s"'+ sLineBreak +'Content-Type: %s'+ sLineBreak+sLineBreak+ '%s';
+var
+  Attachment: TMultiPartFormAttachment;
+begin
+  if Field.FieldType.TypeKind in [tkString, tkUString, tkWChar, tkLString, tkWString, tkInteger, tkChar, tkWChar] then
+  begin
+    Content.Add(Format(FmtTextContent, [Field.Name, Field.GetValue(Self).AsString]));
+    Exit;
+  end;
+
+  if Field.FieldType.Name.Equals(TMultiPartFormAttachment.ClassName) then
+  begin
+    Attachment := Field.GetValue(Self).AsType<TMultiPartFormAttachment>;
+    Content.Add(Format(FmtFileContent, [Field.Name, Attachment.FileName, Attachment.MimeType, Attachment.Content.DataString]));
+  end;
+end;
+
+function TMultiPartFormData.ContentAsString: string;
+var
+  vField: TRttiField;
+  vContent: TStringList;
+  vBoundary: string;
+  vRttiContext: TRttiContext;
+  vRttiType: TRttiType;
+begin
+  vBoundary := '--' + FBoundary;
+
+  vContent := TStringList.Create;
+  try
+    vContent.Add(vBoundary);
+
+    vRttiContext := TRttiContext.Create;
+    vRttiType := vRttiContext.GetType(Self.ClassType);
+    for vField in vRttiType.GetDeclaredFields do
+    begin
+      AddFieldContent(vField, vContent);
+      vContent.Add(vBoundary);
+    end;
+
+    vContent.Strings[Pred(vContent.Count)] := vBoundary + '--';
+    Result := vContent.Text;
+  finally
+    vContent.Free;
+  end;
+end;
+
+constructor TMultiPartFormData.Create;
+const
+  FmtBoundary = 'boundary--%s';
+  FmtContentType = 'multipart/form-data; boundary=%s';
+var
+  vGUID: TGUID;
+begin
+  CreateGUID(vGUID);
+  FBoundary := Format(FmtBoundary, [GUIDToString(vGUID)]);
+  FContentType := Format(FmtContentType, [FBoundary]);
+end;
+
+constructor TMultiPartFormAttachment.Create(Source: TStream; MimeType, FileName: string);
+begin
+  Create(MimeType, FileName);
+  FContent.LoadFromStream(Source);
+end;
+
+constructor TMultiPartFormAttachment.Create(FilePath, MimeType, FileName: string);
+begin
+  Create(MimeType, FileName);
+  FContent.LoadFromFile(FilePath);
+end;
+
+constructor TMultiPartFormAttachment.Create(MimeType, FileName: string);
+begin
+  FContent := TStringStream.Create;
+  FMimeType := MimeType;
+  FFileName := FileName;
+end;
+
+destructor TMultiPartFormAttachment.Destroy;
+begin
+  FContent.Free;
+  inherited;
+end;
+{$ENDIF}
+
 end.